VBA – Bayan Bus Algorithms

Some one year ago there was something called Bayan 2015 Contest, published in codeforces.com. Thus, I have decided to solve one of the contest problems with VBA in Excel. And actually, as expected I have managed to do it! 😀

Here is the contest link of the problem

The problem looks like this:

The final round of Bayan Programming Contest will be held in Tehran, and the participants will be carried around with a yellow bus. The bus has 34 passenger seats: 4 seats in the last row and 3 seats in remaining rows.

$\text{[math]}$ The event coordinator has a list of k participants who should be picked up at the airport. When a participant gets on the bus, he will sit in the last row with an empty seat. If there is more than one empty seat in that row, he will take the leftmost one.

In order to keep track of the people who are on the bus, the event coordinator needs a figure showing which seats are going to be taken by k participants. Your task is to draw the figure representing occupied seats.

Input

The only line of input contains integer k, (0 ≤ k ≤ 34), denoting the number of participants.

Output

Print the figure of a bus with k passengers as described in sample tests. Character ‘#‘ denotes an empty seat, while ‘O‘ denotes a taken seat. ‘D‘ is the bus driver and other characters in the output are for the purpose of beautifying the figure. Strictly follow the sample test cases output format. Print exactly six lines. Do not output extra space or other characters.

So, what did I do? An Excel formula, getting the input and giving the output. Of course, the font must be a console font, where all signs take the same width and height. Pretty much like this:

bus

What I do in my code? I simply take the bus as an array of strings and I change each seat correspondingly to taken or to not taken. The trick is to know which is the next seat, as far as the last row has 4 seats and the others have 3. That’s why I have so many conditions. If you run the public sub TestBus(), you would get all the possibilities in the console :D.

Long story short – that is it! 😀

Here comes the code:

Public Function WriteString(ByVal n As Long) As String
    'Lucida Console or Consolas
    Dim v_Bus()     As Variant
    Dim s_char      As String
    
    Dim i           As Long
    Dim l_col       As Long
    Dim l_row       As Long
    
    n = n - 1
    v_Bus = Array("+------------------------+", _
                  "|......................|D|)", _
                  "|......................|.|", _
                  "|........................|", _
                  "|......................|.|)", _
                  "+------------------------+")
    
    For i = 0 To 33
        
        If i > n Then
            s_char = "#"
        Else
            s_char = "O"
        End If

        If i < 4 Then
            l_col = 0
        ElseIf i = 4 Then
            l_col = 1
        Else
            l_col = (i - 2) / 3
        End If

        If i <= 3 Then
            l_row = i
        Else
            l_row = (i - 4) Mod 3
        End If

        If (l_row = 2 And l_col <> 0) Then l_row = l_row + 1
        Mid(v_Bus(l_row + 1), (1 + l_col * 2) + 1, 1) = s_char
    Next i
    
    WriteString = draw_bus(v_Bus)

End Function

Public Function draw_bus(v_Bus As Variant) As String
    
    Dim i As Long
    For i = LBound(v_Bus) To UBound(v_Bus)
        draw_bus = draw_bus & v_Bus(i) & vbCrLf
    Next i
    
End Function

Public Sub TestBus()
    
    Dim l_counter As Long

    For l_counter = 1 To 34
        Debug.Print l_counter
        Debug.Print WriteString(l_counter)
    Next l_counter
End Sub

Available in GitHub.com as well!

VBA – Bayan Bus Algorithms

Related posts: